Scripts de sauvegarde Windows (Networker)

Fiche express
Domaine	Procédure d'exploitation
Objectif	Script batch pré/post-sauvegarde Windows : capturer l'état des services et de l'environnement autour d'une sauvegarde NetWorker
Voir aussi	Save (Networker) · Savegrp

Ce script batch Windows illustre un enchaînement pré-commande / commande de sauvegarde / post-commande appelé par savegrp : il capture la liste des services démarrés avant la sauvegarde, lance save.exe avec les arguments transmis, puis capture les variables d'environnement après la sauvegarde.

Script

@ECHO OFF
SETLOCAL
ECHO =======START BATCH FILE================
ECHO =====NetWorker PRE_BACKUP COMMAND======
ECHO =======NET START - cree le fichier netstart.txt et
ECHO =======envoie toutes les informations des services demarres
ECHO =======au fichier c:\netstart.txt
NET START >>C:\NETSTART.TXT

REM Cette commande utilise les arguments entrants de la commande savegrp
REM et les traite pour depasser les limites du fichier batch : PARSE ALL
REM INCOMING ARGUMENTS, et passe un seul argument au cas ou plus de 10
REM arguments sont transmis a ce fichier (%0-%9 n'est pas suffisant).
ECHO =====NetWorker SAVE SET COMMAND=======
SHIFT
SET arg=%0
:loop
SHIFT
IF %0.==. GOTO save
SET arg=%arg% %0
GOTO loop

REM Ce sont les commandes save qui executent les commandes NetWorker
REM de sauvegarde requises.
:save
REM Remarque : saisir le chemin correct vers le repertoire bin de NetWorker
REM (ligne ci-dessous : chemin par defaut)
C:\PROGRA~1\nsr\bin\save.exe %arg%

ECHO =====NetWorker POST_BACKUP COMMAND====
ECHO ====="SET" - cree le fichier set.txt et envoie toutes les
ECHO =====informations de l'environnement systeme de l'ordinateur
ECHO =====au fichier C:\set.txt
SET >>C:\SET.TXT
ECHO ======END OF BATCH FILE====
ENDLOCAL

Voir aussi

• Save (Networker) — commande save.exe appelée par ce script
• Savegrp — transmet les arguments de sauvegarde au script